kind := "bazel run --config=quiet //hack/tools:kind --"
kubectl := "bazel run --config=quiet //hack/tools:kubectl --"
kustomize := "bazel run --config=quiet //hack/tools:kustomize --"
# kind cluster name
name := "edge"

# registry information
registry_name := "kind-registry"
registry_port := "21700"

up: registry
  {{kind}} create cluster --config $(pwd)/config.yaml --name {{name}} --wait 5m
  # make our local registry available to our kind cluster
  if [ "$(docker inspect -f='{{{{json .NetworkSettings.Networks.kind}}' "{{registry_name}}")" = 'null' ]; then \
    docker network connect "kind" "{{registry_name}}"; \
  fi
  {{kubectl}} apply -f local-registry-config.yaml

down:
  {{kind}} delete cluster --name {{name}}

reset: down up

install-kcc infra-cluster-id infra-project-id: ensure-kind
  echo "dumping cluster info..."
  {{kubectl}} cluster-info
  echo "installing and configuring kcc..."
  bazel run --config=quiet //cmd/lift -- setup konfig-konnector --cluster-id={{infra-cluster-id}} --cluster-project-id={{infra-project-id}} --cluster-type=generic

ensure-kind:
  ./check-kind-context.sh "{{kubectl}}"

registry:
  #!/usr/bin/env bash
  if [ "$(docker inspect -f '{{{{.State.Running}}' "{{registry_name}}" 2>/dev/null || true)" != "true" ]; then 
    docker run \
      -d --restart=always \
      -p "127.0.0.1:{{registry_port}}:5000" \
      --name "{{registry_name}}" \
      registry:2
  fi