"""Defines shellcheck external dependencies"""

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

SHELLCHECK_VERSIONS = {
    "v0.7.2": {
        "darwin.x86_64": "969bd7ef668e8167cfbba569fb9f4a0b2fc1c4021f87032b6a0b0e525fb77369",
        "linux.x86_64": "70423609f27b504d6c0c47e340f33652aea975e45f312324f2dbf91c95a3b188",
    },
}

def shellcheck_dependencies():
    """Returns http_archives for shellcheck."""
    version = SHELLCHECK_VERSIONS.keys()[0]

    for platform in SHELLCHECK_VERSIONS[version].keys():
        http_archive(
            name = "shellcheck_" + platform.replace(".", "_"),
            build_file_content = """
package(default_visibility = ["//visibility:public"])

filegroup(
  name = "file",
  srcs = glob(["shellcheck-{0}/shellcheck"]),
  visibility = ["//visibility:public"]
)
""".format(version),
            sha256 = SHELLCHECK_VERSIONS[version][platform],
            urls = [
                "https://github.com/koalaman/shellcheck/releases/download/{version}/shellcheck-{version}.{platform}.tar.xz".format(
                    version = version,
                    platform = platform,
                ),
            ],
        )